excel常用函数公式大全
7天，整理出 HR常用的Excel函数公式大全(共21个)
excel常用函数公式大全在HR同事电脑中，兰色经常看到海量的Excel表格，员工基本信息、提成计算、考勤统计、合同管理….看来再完备的HR系统也取代不了表格的作用。一周前，兰色交给小助理木炭一个任务，尽可能多的收集HR工作中的Excel公式。进行了整理编排，于是有了这篇本平台史上最全HR的Excel公式+数据分析技巧集。
一、员工信息表公式
1、计算性别(F列)
=IF(MOD(MID(E3,17,1),2),”男”,”女”)
2、出生年月(G列)
=TEXT(MID(E3,7,8),”0-00-00″)
3、年龄公式(H列)
=DATEDIF(G3,TODAY(),”y”)
4、退休日期(I列)
=TEXT(EDATE(G3,12*(5*(F3=”男”)+55)),”yyyy/mm/dd aaaa”)
5、籍贯(M列)
=VLOOKUP(LEFT(E3,6)*1,地址库!E:F,2,)
注：附带示例中有地址库代码表
6、社会工龄(T列)
=DATEDIF(S3,NOW(),”y”)
7、公司工龄(W列)
=DATEDIF(V3,NOW(),”y”)&”年”&DATEDIF(V3,NOW(),”ym”)&”月”&DATEDIF(V3,NOW(),”md”)&”天”
8、合同续签日期(Y列)
=DATE(YEAR(V3)+LEFTB(X3,2),MONTH(V3),DAY(V3))-1
9、合同到期日期(Z列)
=TEXT(EDATE(V3,LEFTB(X3,2)*12)-TODAY(),”[<0]过期0天;[<30]即将到期0天;还早”)
10、工龄工资(AA列)
=MIN(700,DATEDIF($V3,NOW(),”y”)*50)
11、生肖(AB列)
=MID(“猴鸡狗猪鼠牛虎兔龙蛇马羊”,MOD(MID(E3,7,4),12)+1,1)
二、员工考勤表公式
1、本月工作日天数(AG列)
=NETWORKDAYS(B$5,DATE(YEAR(N$4),MONTH(N$4)+1,),)
2、调休天数公式(AI列)
=COUNTIF(B9:AE9,”调”)
3、扣钱公式(AO列)
婚丧扣10块，病假扣20元，事假扣30元，矿工扣50元
=SUM((B9:AE9={“事”;”旷”;”病”;”丧”;”婚”})*{30;50;20;10;10})
四、员工数据分析公式
1、本科学历人数
=COUNTIF(D:D,”本科”)
2、办公室本科学历人数
=COUNTIFS(A:A,”办公室”,D:D,”本科”)
3、30~40岁总人数
=COUNTIFS(F:F,”>=30″,F:F,”<40″)
五、其他公式
1、提成比率计算
=VLOOKUP(B3,$C$12:$E$21,3)
2、个人所得税计算
假如A2中是应税工资，则计算个税公式为：
=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)
3、工资条公式
=CHOOSE(MOD(ROW(A3),3)+1,工资数据源!A$1,OFFSET(工资数据源!A$1,INT(ROW(A3)/3),,),””)
注：
A3:标题行的行数+2,如果标题行在第3行，则A3改为A5
工资数据源!A$1:工资表的标题行的第一列位置
4、Countif函数统计身份证号码出错的解决方法
由于Excel中数字只能识别15位内的，在Countif统计时也只会统计前15位，所以很容易出错。不过只需要用&”*”转换为文本型即可正确统计。
=Countif(A:A,A2&”*”)
=–TEXT(MID(A2,7,8),”0-00-00″)
6、根据身份证号码提取性别
=IF(MOD(MID(A2,15,3),2),”男”,”女”)
7、几个常用的汇总公式
A列求和：=SUM(A:A)
A列最小值：=MIN(A:A)
A列最大值：=MAX (A:A)
A列平均值：=AVERAGE(A:A)
A列数值个数：=COUNT(A:A)
8、成绩排名
=RANK.EQ(A2,A$2:A$7)
9、中国式排名(相同成绩不占用名次)
=SUMPRODUCT((B$2:B$7>B2)/COUNTIF(B$2:B$7,B$2:B$7))+1
10、90分以上的人数
=COUNTIF(B1:B7,”>90″)
11、各分数段的人数
同时选中E2:E5，输入以下公式，按Shift+Ctrl+Enter
=FREQUENCY(B2:B7,{70;80;90})
12、按条件统计平均值
=AVERAGEIF(B2:B7,”男”,C2:C7)
13、多条件统计平均值
=AVERAGEIFS(D2:D7,C2:C7,”男”,B2:B7,”销售”)
14、统计不重复的个数
=SUMPRODUCT(1/COUNTIF(A2:A9,A2:A9))
15提取不重复的内容
C2单元格输入以下数组公式，按Ctrl+ Shift+Enter，向下复制。
=INDEX(A:A,1+MATCH(,COUNTIF(C$1:C1,A$2:A$10),))&””
以上列举了一些常用的模式化公式，限于篇幅，没有对函数进行深入讲解。
转载请注明：约嗲社区 yuedia.com
